mirror of
https://fuchsia.googlesource.com/third_party/pigweed.googlesource.com/pigweed/pigweed
synced 2024-09-21 14:16:26 +00:00
d49f8fe3f3
The "# gn-format disable" comments are no longer necessary. Delete these comments and reformat with a Vim macro and gn format. Change-Id: Ia62c40ad73eef91187d0d443d6e3b0fa723e5aa9 Reviewed-on: https://pigweed-review.googlesource.com/c/pigweed/pigweed/+/21380 Reviewed-by: Armando Montanez <amontanez@google.com> Commit-Queue: Wyatt Hepler <hepler@google.com>
51 lines
1.8 KiB
Plaintext
51 lines
1.8 KiB
Plaintext
# Copyright 2020 The Pigweed Authors
|
|
#
|
|
# Licensed under the Apache License, Version 2.0 (the "License"); you may not
|
|
# use this file except in compliance with the License. You may obtain a copy of
|
|
# the License at
|
|
#
|
|
# https://www.apache.org/licenses/LICENSE-2.0
|
|
#
|
|
# Unless required by applicable law or agreed to in writing, software
|
|
# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
|
|
# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
|
|
# License for the specific language governing permissions and limitations under
|
|
# the License.
|
|
|
|
import("//build_overrides/pigweed.gni")
|
|
|
|
import("$dir_pigweed/targets/stm32f429i-disc1/target_toolchains.gni")
|
|
import("$dir_pw_docgen/docs.gni")
|
|
import("$dir_pw_protobuf_compiler/proto.gni")
|
|
import("$dir_pw_third_party/nanopb/nanopb.gni")
|
|
import("$dir_pw_toolchain/arm_gcc/toolchains.gni")
|
|
import("$dir_pw_toolchain/generate_toolchain.gni")
|
|
|
|
# Toolchain for generating upstream Pigweed documentation.
|
|
generate_toolchain("docs") {
|
|
# Use the stm32f429i-disc1 toolchain for pw_size_report targets.
|
|
_base_toolchain = pw_target_toolchain_stm32f429i_disc1.size_optimized
|
|
forward_variables_from(_base_toolchain,
|
|
"*",
|
|
[
|
|
"defaults",
|
|
"name",
|
|
])
|
|
defaults = {
|
|
forward_variables_from(_base_toolchain.defaults, "*")
|
|
|
|
_has_nanopb_rpc = pw_protobuf_GENERATORS + [ "nanopb_rpc" ] -
|
|
[ "nanopb_rpc" ] != pw_protobuf_GENERATORS
|
|
if (dir_pw_third_party_nanopb != "" && !_has_nanopb_rpc) {
|
|
pw_protobuf_GENERATORS += [ "nanopb_rpc" ]
|
|
}
|
|
|
|
# This is the docs target.
|
|
pw_docgen_BUILD_DOCS = true
|
|
}
|
|
}
|
|
|
|
pw_doc_group("target_docs") {
|
|
sources = [ "target_docs.rst" ]
|
|
}
|