mirror of
https://fuchsia.googlesource.com/third_party/pigweed.googlesource.com/pigweed/pigweed
synced 2024-09-20 13:51:05 +00:00
c8b939009b
The GN convention is to specify paths in command lines relative to the build directory. Unfortunately and contrary to pigweed's expectations this is not what rebase_path(path) does; that outputs an absolute path. Absolute paths are not desirable in most circumstances as they contain sources of nondeterminism such as the developer's home directory. Using them can for example reduce hit rate in build caches. Replace rebase_path(path) with rebase_path(path, root_build_dir) which is the correct idiom and matches GN's builtin behavior (e.g. for sources, include_dirs, etc). This also removes the --directory argument to python_action(). Changing the directory during the build while using relative paths is likely to result in confusion and should be discouraged. There's a couple more things to do on top of this for identical binaries between build directories / machines / developers: - pass options to avoid embedding the working directory - pass options to use relative paths for the vendored clang & libc++ See [1]-[2] for how to do that. [1] https://source.chromium.org/chromium/chromium/src/+/main:build/config/compiler/BUILD.gn;l=1170-1239;drc=ab531c265c533cba1c2f6d8240cc0bf7679f605a [2] https://cs.opensource.google/fuchsia/fuchsia/+/main:build/config/BUILD.gn;l=145-216;drc=f6d705f0937c778d5d5f807a4580113612b02f5a Change-Id: I17708102c03d6488d68c8571b6e9343191fd47de Reviewed-on: https://pigweed-review.googlesource.com/c/pigweed/pigweed/+/47461 Reviewed-by: Wyatt Hepler <hepler@google.com> Commit-Queue: Michael Spang <spang@google.com>
121 lines
3.3 KiB
Plaintext
121 lines
3.3 KiB
Plaintext
# Copyright 2021 The Pigweed Authors
|
|
#
|
|
# Licensed under the Apache License, Version 2.0 (the "License"); you may not
|
|
# use this file except in compliance with the License. You may obtain a copy of
|
|
# the License at
|
|
#
|
|
# https://www.apache.org/licenses/LICENSE-2.0
|
|
#
|
|
# Unless required by applicable law or agreed to in writing, software
|
|
# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
|
|
# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
|
|
# License for the specific language governing permissions and limitations under
|
|
# the License.
|
|
|
|
import("//build_overrides/pigweed.gni")
|
|
|
|
import("$dir_pw_build/target_types.gni")
|
|
import("$dir_pw_docgen/docs.gni")
|
|
import("$dir_pw_unit_test/test.gni")
|
|
|
|
config("public") {
|
|
include_dirs = [ "public" ]
|
|
visibility = [ ":*" ]
|
|
}
|
|
|
|
pw_source_set("pw_polyfill") {
|
|
public_configs = [ ":public" ]
|
|
remove_public_deps = [ "*" ]
|
|
public_deps = [ ":standard_library" ]
|
|
public = [
|
|
"public/pw_polyfill/language_feature_macros.h",
|
|
"public/pw_polyfill/standard.h",
|
|
]
|
|
}
|
|
|
|
config("overrides_config") {
|
|
include_dirs = [ "public_overrides" ]
|
|
cflags_cc = [
|
|
# Use -include to include the language features header in dependent files,
|
|
# without requiring a #include. This allows the use of newer C++ language
|
|
# features in older C++ versions without an explicit include.
|
|
"-include",
|
|
rebase_path("language_features.h", root_build_dir),
|
|
]
|
|
visibility = [ ":*" ]
|
|
}
|
|
|
|
pw_source_set("overrides") {
|
|
public_configs = [ ":overrides_config" ]
|
|
remove_public_deps = [ "*" ]
|
|
public_deps = [
|
|
":standard_library",
|
|
"$dir_pw_span:polyfill",
|
|
]
|
|
inputs = [
|
|
"public_overrides/array",
|
|
"public_overrides/assert.h",
|
|
"public_overrides/bit",
|
|
"public_overrides/cstddef",
|
|
"public_overrides/iterator",
|
|
"public_overrides/type_traits",
|
|
"public_overrides/utility",
|
|
]
|
|
sources = [ "language_features.h" ]
|
|
}
|
|
|
|
config("standard_library_public") {
|
|
include_dirs = [ "standard_library_public" ]
|
|
}
|
|
|
|
pw_source_set("standard_library") {
|
|
public_configs = [ ":standard_library_public" ]
|
|
remove_public_deps = [ "*" ]
|
|
public = [
|
|
"standard_library_public/pw_polyfill/standard_library/array.h",
|
|
"standard_library_public/pw_polyfill/standard_library/assert.h",
|
|
"standard_library_public/pw_polyfill/standard_library/bit.h",
|
|
"standard_library_public/pw_polyfill/standard_library/cstddef.h",
|
|
"standard_library_public/pw_polyfill/standard_library/iterator.h",
|
|
"standard_library_public/pw_polyfill/standard_library/namespace.h",
|
|
"standard_library_public/pw_polyfill/standard_library/type_traits.h",
|
|
"standard_library_public/pw_polyfill/standard_library/utility.h",
|
|
]
|
|
visibility = [
|
|
":overrides",
|
|
":pw_polyfill",
|
|
]
|
|
}
|
|
|
|
pw_test_group("tests") {
|
|
tests = [
|
|
":default_cpp_test",
|
|
":cpp11_test",
|
|
":cpp14_test",
|
|
]
|
|
group_deps = [ "$dir_pw_span:tests" ]
|
|
}
|
|
|
|
pw_test("default_cpp_test") {
|
|
deps = [ ":pw_polyfill" ]
|
|
sources = [ "test.cc" ]
|
|
}
|
|
|
|
pw_test("cpp11_test") {
|
|
remove_configs = [ "$dir_pw_build:cpp17" ]
|
|
configs = [ "$dir_pw_build:cpp11" ]
|
|
sources = [ "test.cc" ]
|
|
deps = [ ":pw_polyfill" ]
|
|
}
|
|
|
|
pw_test("cpp14_test") {
|
|
remove_configs = [ "$dir_pw_build:cpp17" ]
|
|
configs = [ "$dir_pw_build:cpp14" ]
|
|
sources = [ "test.cc" ]
|
|
deps = [ ":pw_polyfill" ]
|
|
}
|
|
|
|
pw_doc_group("docs") {
|
|
sources = [ "docs.rst" ]
|
|
}
|